Title: SNAKE VERSION 4
Version: 4
Author: Quick Edge
Size: ca 870 byte
Model: FX 9750G, CFX 9850G, CFX 9950G
Description: Snake is a fast, fun, uncomplicated game. You are a snake and you shall
collect numbers (1-9). For every number you take your points rise with that number.

Keys:
You use the arrow keys to steer the snake.
[4] (P as in Pause) to pause the game. 

================================================================
New for version 4 is:
* Faster to get into "the game" You doesn't have to choose speed etc. if the standard is good.
* Nicer design.
* Better control of the snake when speed is low
* Better point display
* Dramatically decreased size

Obs. You can't go down to the last row.
================================================================
Command translation:

-> Single arrow (located on the keyboard)
=> Double arrow (press: [shift] [prgm] [f1] [f1])
_ Display, -Disp- (press: [shift] [prgm] [f4])
<= Less or equal (A <= B)
>= Greater or equal (A >= B)
<> Not equal (A <> B)
/ Division or fraction

Find the commands:
Lbl [SHIFT] [VARS] [F3] [F1]
Locate [SHIFT] [VARS] [F6] [F4] [F1]
~ [ALPHA] [F3]
ClrText [SHIFT] [VARS] [F6] [F1] [F1]
Int [OPTN] [F6] [F4] [F2]
Isz [SHIFT] [VARS] [F3] [F4]
Dsz [SHIFT] [VARS] [F3] [F5]
GetKey [SHIFT] [VARS] [F6] [F4] [F2]
=> [SHIFT] [VARS] [F3] [F3]
= , < , > [SHIFT] [VARS] [F6] [F3] + [F1] or [F3] or [F4]
Goto [SHIFT] [VARS] [F3] [F2]
Or [OPTN] [F6] [F6] [F4] [F2]
And [OPTN] [F6] [F6] [F4] [F1]
? [SHIFT] [VARS] [F4]
Do [SHIFT] [VARS] [F1] [F3]
LpWhile [SHIFT] [VARS] [F1] [F4]
Ran# [OPTN] [F6] [F3] [F4]
For, To, Next [SHIFT] [VARS] [F1] [F6] + [F1] or [F2] or [F4]
_ [SHIFT] [VARS] [F5]
_________________________________________________________________________
Everything in-between the { } are comments and should not be typed into your calculator.
_________________________________________________________________________

Program: Snake 4

Lbl 1
0->A~Z
3->Q {standard times to play}
10->K {standard speed}
Lbl 2
ClrText
If X=72
Then "NR OR TIMES TO PLAY":?->Q
IfEnd
If X=62
Then "SPEED? (1-10)":?->K
IfEnd
(K-11)/-1->Z
ClrText
Locate 1,1,"XXXXXXX SNAKE XXXXXXX"
Locate 3,3,"1. NR OF TIMES [ ]" {double space}
Locate 3,4,"2. SPEED [ ]" {double space}
Locate 3,5,"3. BEGIN [EXE]"
Locate 20-Int (Q/10,3,Q
Locate 14-Int (K/10,4,K
Do
Getkey->X
X=72 Or X=62=>Goto 2
LpWhile X<>31 And X<>73
Lbl 3
T=73=>Locate 7,2,"==Pause=="_
ClrText
2->E:27->U:3->F~J:5->B:4->C:3->D
For 2->A To 5
Locate A,F,"O"
Next
Isz A
Lbl 4
M+P->P
Int 9Ran#+1->M
Int 21Ran#+1->N
Int 7Ran#+1->O
A=N And F=O Or B=N And G=O Or C=N And H=O Or D=N And I=O Or E=N And J=O=>Goto 4
Locate N,O,M
Do
Locate A,F,"O"
Locate E,J," " {1 space}
D->E:C->D:B->C:A->B:I->J:H->I:G->H:F->G
For 1->L To Z
Getkey->T
T>0=>T->U
Next
U=28=>Dsz F
U=38=>Dsz A
U=27=>Isz A
U=37=>Isz F
U=73=>Goto 3
A=N And F=O=>Goto 4
LpWhile A<22 And A>0 And F<8 And F>0
ClrText
Isz R
For 2->S To 7 Step 5
Locate 1,S,"+++++++++++++++++++++" {21 +}
Next
R=Q=>Locate 5,2,"--GAME OVER--"
Locate 2,4,"YOUR POINTS ARE:"
Locate 11,7,R
Locate 18,4,P_
If R>1
Then Locate 2,5,"THIS TIME:"
Locate 18,5,P-Y_
IfEnd
P->Y
0->M
R=Q=>Goto 1
Goto 3

________________________________________________________________________