\START85\
\COMMENT=Program file dated 01/10/96, 18:19
\NAME=Mndlbrot
\FILE=MNDLBROT.85P
:ClLCD
:ClDrw
:FnOff 
:Menu(1,"NEW",NEW,2,"RESME",RES)
:Lbl NEW
:Input "BAILOUT (0-DEFAULT): ",Mm
:If Mm==0
:4\->\Mm
:Input "MAX ITER: ",Z
:If fPart (Z/2)==.0
:Z+1\->\Z
:Input "MIN X: ",xMin
:Input "MAX X: ",xMax
:Input "MIN Y: ",yMin
:Input "MAX Y: ",yMax
:yMin\->\Q
:yMax\->\R
:If (yMin*yMax)<0
:Then
:If abs (yMin)>abs (yMax)
:0\->\R
:If abs (yMax)\>=\abs (yMin)
:0\->\Q
:End
:xMin\->\X
:Lbl A
:If X\>=\xMax
:Goto E
:Q\->\Y
:Lbl B
:If Y\>=\R
:Then
:X+\Delta-x\\->\X
:Goto A
:End
:Lbl RST
:X\->\S
:Y\->\T
:0\->\I
:Lbl C
:S\^2\-T\^2\+X\->\U
:2*S*T+Y\->\V
:U\->\S
:V\->\T
:I+1\->\I
:If S\^2\+T\^2\>Mm
:Goto D
:If I<Z
:Goto C
:Lbl D
:If fPart (I/2)==.5
:Then
:PtOn(X,Y)
:PtOn(X,\(-)\Y)
:End
:Y+\Delta-y\\->\Y
:If getKy==15
:Goto BACK
:Goto B
:Lbl E
:StPic MSAVE
:FnOn 
:Stop
:Lbl BACK
:Mm\->\MmS
:Z\->\ZS
:xMin\->\xMinS
:xMax\->\xMaxS
:yMin\->\yMinS
:yMax\->\yMaxS
:X\->\XS
:Y\->\YS
:Q\->\QS
:R\->\RS
:StPic MANDS
:FnOn 
:Stop
:Lbl RES
:MmS\->\Mm
:ZS\->\Z
:xMinS\->\xMin
:xMaxS\->\xMax
:yMinS\->\yMin
:yMaxS\->\yMax
:XS\->\X
:YS\->\Y
:QS\->\Q
:RS\->\R
:RcPic MANDS
:Goto RST
\STOP85\