\START85\
\COMMENT=Program file dated 01/10/96, 18:19
\NAME=Space
\FILE=SPACE.85P
:ClLCD
:Input "Step: ",G
:Disp "Perspective"
:Input "(Normally 1.05): ",H
:AxesOff
:FnOff 
:dim OBJ\->\L
:L(1)\->\R
:L(2)\->\A
:R\->\dim P
:R\->\dim Q
:Lbl ST
:round(OBJ,8)\->\OBJ
:ClDrw
:For(N,1,R)
:OBJ(N,1)/(H^OBJ(N,3))\->\P(N)
:OBJ(N,2)/(H^OBJ(N,3))\->\Q(N)
:PtOn(P(N),Q(N))
:End
:For(N,1,R)
:For(S,4,A)
:If OBJ(N,S)\<>\0
:Then
:OBJ(N,S)\->\Z
:Line(P(N),Q(N),P(Z),Q(Z))
:End
:End
:End
:Menu(1,"UP",UP,2,"DOWN",DOWN,3,"LEFT",LEFT,4,"RIGHT",RIGHT,5,"OPTS.",O\#\
PTS)
:Lbl UP
:\(-)\G\->\V
:2\->\D
:Goto VER
:Lbl DOWN
:G\->\V
:2\->\D
:Goto VER
:Lbl LEFT
:G\->\V
:1\->\D
:Goto VER
:Lbl RIGHT
:\(-)\G\->\V
:1\->\D
:Lbl VER
:For(M,1,R)
:[[OBJ(M,D),OBJ(M,3)]]\->\B
:B*[[cos V,\(-)\sin V][sin V,cos V]]\->\B
:B(1,1)\->\OBJ(M,D)
:B(1,2)\->\OBJ(M,3)
:End
:Goto ST
:Lbl OPTS
:Menu(1,"Z-IN",IN,2,"Z-OUT",OUT,3,"RANGE",RNG,4,"Z-SQR",ZSQ,5,"QUIT",QU\#\
IT)
:Lbl IN
:ZIn
:Goto ST
:Lbl OUT
:ZOut
:Goto ST
:Lbl RNG
:ClLCD
:Prompt xMin
:Prompt xMax
:Prompt yMin
:Prompt yMax
:Prompt xFact
:Prompt yFact
:Goto ST
:Lbl ZSQ
:ZSqr
:Goto ST
:Lbl QUIT
:FnOn 
:AxesOn
:Stop
\STOP85\