Dao 與 SQL 語法範例(三)

回首頁

分類

標題

大意

作者

日期
Dao 操作 逐步取回大型資料庫的記錄 　 老怪 1998/11/13
Dao 操作 設定欄位的預設值 Field.DefaultValue 屬性的使用 老怪 1998/11/13
Dao 操作 如何把 FieldValue 放到 ComboBox 裏 Recordset 迴圈的製作 老怪 1998/11/18
Dao 操作 用 ComBo 操作兩個欄位記錄 ItemData 屬性使用 老怪 1999/1/22
Dao 操作 讓兩個 Combo 依 Record 連動 　 老怪 1998/11/26
Dao 操作 Recordset.Filter 和 SQL WHERE 的使用 Recordset 的條件查詢 老怪 1998/11/28
Dao 操作 如何還原日期欄位為未輸入型態 FieldName.Value=Null 老怪 1999/1/16
Dao 操作 開啟資料庫中任一資料表 TabDefs 集合物件使用 老怪 1999/2/12
SQL 語法 列出特定時間區段的所有記錄 Between 的條件查詢 老怪 1998/12/3
SQL 語法 為資料記錄做群組分項統計 GROUP BY 敘述 老怪 1999/1/20
SQL 語法 將連接的網路資料表存入本機資料庫 產生資料表查詢的使用 老怪 1999/1/22
SQL 語法 在 SQL 字串中插入 ['] 字元 Chr(Ascii Code) 的使用 老怪 1999/1/28
DBGrid 兩個不同設定的 DBGrid 同步 Columns.Visible 屬性的利用 老怪 1998/11/19
DBGrid 儲存 DBGrid.Columns.Width 的設定 Field.Property 物件的利用 老怪 1998/11/19
DBGrid 設定欄位名稱 Column.Caption 屬性的使用 老怪 1998/12/15
DBGrid 列印 DBGrid Cell 裏的資料(1999/4/3 修正) DBGrid.CellText 方法的使用 老怪 1998/12/31
DBGrid 多欄及多列選取 　 老怪 1999/1/4
DBList 用 DBList_Click 移動記錄指標 SelectItem 屬性的使用 老怪 1998/12/25
資料分析 應當分割的資料表 資料細分的觀念 老怪 1998/12/15
資料分析 再談資料庫欄位中 Null 值的處理 資料庫安全與使用者便利 老怪 1999/1/16

Dao 與 SQL 語法範例使用說明

  1. 本資料庫範例只適用 Dao 物件，單一使用者的操作，多使用者及網路上的使用，因有更多的限制，本範例未必能正確執行。本範例歡迎非營利性個人及組織轉載使用，營利之利用請先徵得本人之同意，來信註明使用方式及回覆地址。
  2. DBGrid、DBCombo 雖屬 VB 外建控制項，但因與 Dao 資料庫息息相關，所以也放本篇討論，而不它歸類在 ActiveX 項。
  3. 本範例所有的程式碼範例，皆屬十分基本的 VB 語法，如果您是個 VB User ，歡迎直接引用或改寫使用在你的程式中 ，本人不主張著作權，因為，沒辦法查嘛。
  4. 如果你是個 VB 初學者，又有點窮窮(和老怪一樣)，趕快把本頁另存新檔到你自己的磁碟，離線後慢慢看，也可以 Copy 給朋友喔(不可以收錢)。
  5. 本範例都是老怪幾個月來在 tw.bbs.comp.language 討論群組中回答版友問題的合輯，因為是針對問題解決，所有並沒有全面觀念的解說，不適合作為入門文章，但如果你讀了入門書，或是上了老師的課，心中仍不甚明白的話，就可以來這找找有沒有你要的答案，因為這都是別人問過的問題。

回索引

逐步取回大型資料庫的記錄

JMilk 撰寫於文章

我要取回資料庫中一大串資料, 可是, 每每都造成逾時.所以, 我想要用 record set 的分頁技巧, 一小部份一小部份的拿回來.煩請賜教.

老怪答：

  1. 你先在 DataTable 裏選定一個 PrimaryKeyField。
  2. 必須使用 SQL TOP 敘述的功能。
  3. 處理的模型是這樣的：
    Dim Db As DataBase
    Dim Rs As Recordset
    Dim Td As TabelDef
    Dim SQLString As String
    Dim TotalCount As Long
    Dim CalcCount As Long
    Dim SeperatKey

    Set Db =OpenDataBase("YourDataBase")
    Set Td=Db.TabelDefs("TabelName")
    TotalCount =Td.RecordCount

    SQLString="Select Top 100 Field(1),Field(2)... Form YourTable Order by
    PrimarykeyField"
    Set Rs=Db.OpenRecordset(SQLString)
    CalcCount=CalcCount+100

    Do While CalcCount<TotalCount
        Rs.MoveLast
        SeperateKey=Rs!PrimaryKeyFieldName
        SQLString="Select Top 100 Field(1),Field(2)... Form YourTable Where
    PrimaryKeyField > "
        & SeperateKey & " Order by PrimarykeyField"
        Set Rs=Db.OpenRecordset(SQLString)
        CalcCount=CalcCount+100
        '你的資料處理動作.....
        '.....................................
        '.....................................
    Loop
  4. 重點是依某一 PrimaryKey 排序後一次開有限的筆數，再把最後一筆記錄的 PrimaryKey 值當做下一循環開啟記錄之Where 條件，你就可以逐段把記錄往下移，不會總是從第一筆開始。

回索引

設定欄位的預設值

寄件者: sam

日期的欄位，在使用他的時候我想設定為當日的日期，但當儲存後，我不想他再跟日期而改，請問要如何做呢？

老怪答：

  1. 用 Access 97 Table 的設計功能，在日期欄位的預設值那欄位裏打 "Date()"。
  2. 用 VB Code
    Dim Db As Database
    Dim Td As TableDef
    Dim Fd As Field
        Set Db = OpenDatabase("YourDataPath&Name")
        Set Td = Db.TableDefs("YourTableName")
        Set Fd = Td.Fields("YourDateTypeFieldName")
        Fd.DefaultValue = "Date()"
  3. 這種用法只能用在 Jet MDB 資料庫。
  4. 如果是打轉換函數字串，應該先查清楚 Access 版本有沒有支援此類函數，函數名稱是指 Access 函數，而不是 VB 函數。

回索引

如何把 FieldValue 放到 ComboBox 裏

安斯烈爾 撰寫於文章

如何用Combo物件，將DataBase中的RecordSource全部讀出來，做成AddItem的方式。

老怪答：

Dim Db as database
Dim Rs as recordset

set Db=opendatabase("YourDataPath&Name")
set Rs=Db.openrecordset("yourtablename")

Rs.MoveFirst

Do While Not Rs.Eof
    combo1.additem Rs!"YourFieldName"
    Rs.MoveNext
Loop

回索引

兩個不同設定的 DBGrid 同步

linux 撰寫於文章

我試著兩個 form 開不同的 DBGrid，用同一個 Data Table ，但一個只顯示一些欄位 , 一個全部都顯示，但我無法同步說。例如 : movenext ,moveprevious,movelast,movefirst 一次移兩個 DBGrid 的記錄指標？

老怪答：

Form1：
把 Data1 的 DataBaseName 和 ReCordSource 設好。

Form2：
    Set Data1.Recordset = Form1.Data1.Recordset
   
    '把不要在 DBGrid 裏顯示的欄位藏起來
    DBGrid1.Columns("Field2Name").Visible = False
    DBGrid1.Columns("Field3Name").Visible = False
    DBGrid1.Columns("Field4Name").Visible = False

回索引

儲存 DBGrid.Columns.Width 的設定

Paper Crane 撰寫於文章

用 DBGrid 看資料時, 每次都要用滑鼠去調欄位寬度，那要怎樣才能把調好的位置存起來 ? 不然每次都要再調一次，屬性欄裡好像沒辦法儲存這項資料ㄋㄝ！

老怪答：

DBGrid1.Columns(Index).Width 屬於執行期設定之屬性，沒辦法保留到下次啟動程式時。實際上 Data 和 DBGrid 都沒有這種屬性設定，不過我們可以把 DBGrid 的 ColumnWidth 資料記到 MDB 資料庫的 Properties 集合裏，很少看到 VB 友用 MDB Property 物件的，這東西可以 CreatNew ，可以 Read and Set (要看屬性狀況，不是所有都適用。)請參考以下範例。
'本範例是利用 Dao Field 物件的 Propertys 集合裏的 ColumnWidth 屬性
'來記錄 DBGrid 的 ColumnWidth 值，使得使用者改變 DBGrid 的 ColumnWidth
'可以保存下來，在下次啟動時維持原來的設定，要注意的是 ColumnWidth 的值
'不在 Data 和 DbGrid 屬性裏，而是存放在 MDB 資料庫本身，這種改變及於
'以 Access 開啟的 Table。
'測試本範例請於表單上布置 Data1,Dbgrid1
Option Explicit
Dim Db As Database
Dim Rs As Recordset
Dim Td As TableDef
'開啟資料表之名稱
Dim TDName As String
'取出 ColumnWidth 的 Property.Value
Private Function GetCellWidth(TempFd As Field) As Single
    '如果 ColumnWidth 的 Property.Value 等於預設值，則先讓
    'DBGrid 的 ColumnWidth =1500
    If TempFd.Properties!ColumnWidth.Value = -1 Then
        TempFd.Properties!ColumnWidth.Value = 1500
        TempFd.Properties.Refresh
    End If
   
    GetCellWidth = TempFd.Properties!ColumnWidth.Value
End Function
'如果發生 ColResize 事件則設定 ColumnWidth 的 Property.Value
Private Sub DBGrid1_ColResize(ByVal ColIndex As Integer, Cancel As Integer)
    SetCellWidth DBGrid1.Columns(ColIndex).DataField, _
            DBGrid1.Columns(ColIndex).Width
End Sub
Private Sub Form_Load()
    TDName = "Student"
    Set Db = OpenDatabase("C:\test\mytest.mdb")
    Set Rs = Db.OpenRecordset(TDName)
    'TabelDef 在此處不能用 Recordset 代替，因為 Field.Propertis 只有用
    'TabelDef 及 QueryDef 才能參照到，用 Recordset 來參照會有無法設定的
    '錯誤
    Set Td = Db.TableDefs(TDName)
   
    Set Data1.Recordset = Rs
    GetAllColWidth
End Sub
'取得先前儲存 Filed.Properties!ColumnWidth 的 Value
Private Sub GetAllColWidth()
Dim I As Integer
Dim SendField As Field
    For I = 0 To DBGrid1.Columns.Count - 1
        Set SendField = Td.Fields(DBGrid1.Columns(I).DataField)
        DBGrid1.Columns(I).Width = GetCellWidth(SendField)
    Next
End Sub
Private Sub Form_Unload(Cancel As Integer)
    Rs.Close
    Db.Close
End Sub
'設定 ColumnWidth 的 Property.Value
Private Sub SetCellWidth(ByVal FDName As String, ByVal CellWidth As Single)
    Td.Fields(FDName).Properties!ColumnWidth.Value = CellWidth
    Td.Fields(FDName).Properties.Refresh
End Sub

回索引

讓兩個 Combo 依 Record 連動

Zima T. 撰寫於文章

若我用兩個 comboxA & comboxB 同時也都連結資料庫 field1 & Field2，當我選取 comboxA(comboxB) 的項目時 如何讓 comboxB(comboxA) 的資料也同時做變動呢?

老怪答：

Option Explicit
Private Sub Combo1_Click()
Dim SearchNo As Long
Dim I As Long
    SearchNo = Combo1.ItemData(Combo1.ListIndex)
   
    For I = 0 To Combo2.ListCount - 1
        If Combo2.ItemData(I) = SearchNo Then
            Combo2.ListIndex = I
            Exit For
        End If
    Next
End Sub
Private Sub Combo2_Click()
Dim SearchNo As Long
Dim I As Long
    SearchNo = Combo2.ItemData(Combo2.ListIndex)
   
    For I = 0 To Combo1.ListCount - 1
        If Combo1.ItemData(I) = SearchNo Then
            Combo1.ListIndex = I
            Exit For
        End If
    Next
End Sub

Private Sub Form_Activate()
    Data1.Recordset.MoveFirst
   
    Do While Not Data1.Recordset.EOF
        Combo1.AddItem Data1.Recordset!Name
        '本範例的重點是 PrimaryKey Serial 欄位是一長整數型態
        '即可把他加在 ItemData 裏做索引
        Combo1.ItemData(Combo1.NewIndex) = Data1.Recordset!Serial
        Combo2.AddItem Data1.Recordset!Note
        Combo2.ItemData(Combo2.NewIndex) = Data1.Recordset!Serial
        Data1.Recordset.MoveNext
    Loop
   
    Combo1.ListIndex = 0
    Combo2.ListIndex = 0
End Sub

回索引

Recordset.Filter 和 SQL WHERE 的使用

寄件者: Young Team Inc.

我製作了一個有關查詢的程式(資料約一萬筆)，在作條件查詢時雖有利用到索引但速度還是很慢；VB中有個 Filter 的功能好像不錯，但我看不太懂使用說明，不知可否教教我有關 Filter 的運用，謝謝。

老怪答：

Option Explicit
Dim Db As Database
Dim Rs As Recordset
Dim Rs1 As Recordset
'利用 Recordset.Filter 屬性作條件查詢
Private Sub Command1_Click()
    Rs.Filter = "Name Like '*D*'"
    Set Rs1 = Rs.OpenRecordset
    Set Data1.Recordset = Rs1
End Sub
'利用 SQL WHERE 敘述作條件查詢
Private Sub Command2_Click()
Dim SQLString As String
    SQLString = "SELECT * FROM Student WHERE Name LIKE '*D*'"
    Set Rs1 = Db.OpenRecordset(SQLString)
    Set Data1.Recordset = Rs1
End Sub
Private Sub Form_Load()
    Set Db = OpenDatabase("c:\test\mytest.mdb")
    '必須指定 Recordset 開啟型態為
    'dynaset
    'snapshot
    'forward-only
    'Filter property 才能使用
    Set Rs = Db.OpenRecordset("student", dbOpenDynaset)
   
    Set Data1.Recordset = Rs
End Sub
Private Sub Form_Unload(Cancel As Integer)
    On Error Resume Next
    Rs.Close
    Rs1.Close
    Db.Close
End Sub

使用 Filter 和 Where 敘述最後的結果是一樣的，但因 Filter 只能適用 Jet MDB 資料庫，為了程式的通用性，還是用 WHERE 敘述比較好。

回索引

列出特定時間區段的所有記錄

海殤君 撰寫於文章

我想由 :select * from table1.db where [TDate] like "1998/4/*"來找出四月份的所有資料.....

老怪答：

select * from table1.db where [TDate] Between #1998/4/1# And #1998/4/30#

回索引

應當分割的資料表

航向夢想的天堂 撰寫於文章

例如:有一台公車 其公車號碼和它行經的各站名要如何處理呢?
>        公車號碼  |    from    |    to
>        ----------------------------
>        287       |  中山市場  |  台北車站
>        287       |  台北車站  |  南陽街
>        247       |  大同公司  |  台泥大樓
>        247       |  台泥大樓  |  美術館
>        247       |  美術館    |  大直

老怪答：

  1. 如果是我，我會用兩個資料表來做關聯：
  2. 一、路線表：
    路線編號  |    from    |    to
    ----------------------------
    001       |  中山市場  |  台北車站
    002       |  台北車站  |  南陽街
    003       |  大同公司  |  台泥大樓
    004       |  台泥大樓  |  美術館
    005       |  美術館    |  大直
  3. 二、公車表：
    公車號碼  |路線編號
    ----------------------------
    287       |001
    287       |002
    287       |003
    247       |003
    247       |004
    247       |005
  4. 列出某號公車經過那些路段
    SQLString="Select 公車表.公車號碼,路線表.from,路線表.to From 公車表 Inner
    Join 路線表 On 公車表.路線編號=路線表.路線編號 Where 公車表.公車號碼 = " &
    varBusNo & ";"
  5. 列出某路段有那些公車經過
    SQLString="Select 公車表.公車號碼,路線表.from,路線表.to From 路線表 Inner
    Join 公車表 On 路線表.路線編號=公車表.路線編號 Where 路線編號.路線編號 = " &
    varsStreetNo & ";"
  6. 更重要的是你應該有路線細分的觀念，我覺得任何兩個站牌間都要算做一段，譬如從天母到員山，經過士林國中、銘傳大學、保齡球館到員山大飯店，如果你籠統的把天母到員山列為一段，那有從社子到士林國中的車子，在資料庫上是沒有交集，可是在實際路線上是有重疊的。資料庫設計，不只考驗程式及資料分析，也考驗你對現實事物分析歸納的能力。

回索引

設定欄位名稱

啦啦啦 撰寫於文章

我開啟dbgrid這個控制項時，那我要如何在每行的行首輸入欄位名稱呢??

老怪答：

使用 DBGrid 的 Column 物件的 Caption 屬性如：
Private Sub Form_Activate()
    DBGrid1.Columns(0).Caption = "給個欄名"
End Sub

回索引

用 DBList_Click 移動記錄指標

dumb 撰寫於文章

List 控制項可利用listindex 指出目前選項位置，請問Dblist 可不可行 有這種功能嗎?要如何做呢?

老怪答：

請使用
DBList.Text 和
DBList.SelectItem 兩個屬性，範例如下：

'執行本範例請於表單布置 Data1,DBList1 ，並在 DBList1 屬性視窗的
'RowSource 欄位填入 Data1。

Option Explicit

Dim TotalRec As Long
Dim Mark As Variant
Dim Db As Database
Dim Rs As Recordset

Private Sub Data1_Reposition()
    Data1.Caption = Rs.AbsolutePosition + 1 & "/" & TotalRec
End Sub

Private Sub DBList1_Click()
    Debug.Print DBList1.Text
    Rs.Bookmark = DBList1.SelectedItem
End Sub

Private Sub Form_Load()
    Set Db = OpenDatabase("c:\test\mytest.mdb")
    Set Rs = Db.OpenRecordset("student", dbOpenDynaset)

    Rs.MoveLast
    TotalRec = Rs.RecordCount
    Rs.MoveFirst
    Set Data1.Recordset = Rs
    DBList1.ListField = "Name"
End Sub

Private Sub Form_Unload(Cancel As Integer)
    Rs.Close
    Db.Close
End Sub

回索引

列印 DBGrid Cell 裏的資料

坐看風起雲湧時 撰寫於文章

VB中如何列印DBGRIDS中的資料?用 printer.print 似乎是不太可行的,有其它的方法嗎?

老怪答：

可以用 Printer.Print 來列印，請參考下例：
Dim I As Long, J As Long
Dim PrintString As String
    For I = 0 To DBGrid1.VisibleRows - 1
        For J = 0 To DBGrid1.Columns.Count - 1
            PrintString = PrintString & DBGrid1.Columns(J).CellText(DBGrid1.RowBookmark(I)) & "/"
        Next
        Printer.Print PrintString
        PrintString = ""
    Next

    Printer.EndDoc

1999/4/3 日修正：

在此向各位抱歉，原本我用 DBGrid.Columns(Index).CellText 這個方法，就是因為不希望指定 Row & Col 會造成捲動拖慢處理速度，結果最後發覺 DBGrid 的 RowBuffer 並不是有多少記錄就設多少列，而是只有可視範圍的列數資料而已，當它捲到下一頁時，才會新 Record 放到原 Buffer 裏。因此要把記錄從頭印到尾，還非捲不可，所以我修正如下，

Option Explicit

Private Sub Command1_Click()
Dim I As Long, J As Long, K As Long
Dim PrintString As String

    For I = 0 To Data1.Recordset.RecordCount - 1
        If K = DBGrid1.VisibleRows Then
            'DBGrid 一定要捲到可視才能其 RowBuffer 才會載入 Data 資料
            DBGrid1.Scroll 0, DBGrid1.VisibleRows
            K = 0
        End If
        For J = 0 To DBGrid1.Columns.Count - 1
            'DBGrid1.RowBookmark 只能抓到 DBGrid 可視的 Record BookMark
            PrintString = PrintString &
DBGrid1.Columns(J).CellText(DBGrid1.RowBookmark(K)) & "/"
        Next
        Printer.Print PrintString
        PrintString = ""
        K = K + 1
        '可以取消此敘述，加上只是讓你看到列印是邊捲 DBGrid 邊執行的。
        DoEvents
    Next
End Sub

Private Sub Form_Activate()
    '在記錄數量很大時,必須把記錄移到最後，否則 Data1 只會塞滿 Buffer 的記錄而已。
    Data1.Recordset.MoveLast
    '必須把記錄捲回開始，以便 DBGrid 列印。
    Data1.Recordset.MoveFirst
    '重要，移到結尾再移回開頭，是為了資料完整並且正確。
End Sub

回索引

多欄及多列選取

弱水三千,只取一瓢飲 撰寫於文章

請問DBGrid可以做到multi-select嗎?

老怪答：

  1. 如果是 Column ，可以直接用滑鼠拖曳 multi-select。
  2. 在程式中用 SelStartCol 和 SelEndCol 偵測使用者選取的 Column。
  3. 如果是 Record ，必須按住 [CTRL] 鍵，再用滑鼠一個一個點取。
  4. 在程式中用 SelBookMarks  物件包含選取資料列書籤的集合，可以用下列方式取出選取列資料：
    Dim I As Integer
        If DBGrid1.SelBookmarks.Count > 0 Then
            For I = 0 To DBGrid1.SelBookmarks.Count - 1
                Debug.Print DBGrid1.Columns(1).CellText(DBGrid1.SelBookmarks.Item(I))
            Next
        End If

回索引

再談資料庫欄位中 Null 值的處理

阿毛 撰寫於文章

在撰寫資料庫的程式時欄位的值該如何取捨??指在Microsoft Access中欄位定義時,允許Null值、必須有值等設定該如何取捨??

老怪答：

Null 值之所以必須避開，是因為它會造成運算失效，也就是任何型態的欄位和變數與Null 做運算，結果都會是 Null，也因此跟著它出來的 Query 和 Recordset 該欄位都會是 Null。如果你只是單純的顯示它，那結果是一個空白，當然沒關係，但如果你做一些欄位結合運算，那含 Null 值計算結果會完全不同於不含 Null 值的計算結果。如果你容許一個欄位有 Null 值，那最後結果將是非你所預期的。

所以在我們剛學習 Access 時，或許大家都不在乎欄位有 Null 值，但隨著資料表增多，彼此關係日益複雜，欄位綜合運算愈來愈多，一個允許 Null 值的欄位設定，將成為一顆埋藏的地雷，它會讓你程式充滿不確定性而無絲毫警告，甚至最後必須該資料表及所有相關的Query、Form、Report 都要重做，這也就是 Access 這麼雞婆，在你欄位為 Null 值時要一再提醒你的原因。

阿毛 撰寫於文章

再者，在撰寫資料庫程式時，使用者所輸入的資料存到資料庫中後，發現必須有值的欄位；使用者未輸入任何值，此時Access會發生錯誤，對於這樣的一個問題不知道是該在程式中加入檢查必須有值的欄位是否已輸入的判斷？還是單靠以資料庫發生錯誤後再去做捕捉資料庫的錯誤的訊息之後再反應給使用者??

老怪答：

你不應該把這訊息告知使用者，因為他沒法理解(也沒責任理解) Null 值對資料庫穩定運作的傷害，他只是想『我先集中輸入此資料庫的這部份欄位，待會我再輸入那一部份欄位。』當你限制他這項自由時，你認為他會怎樣評價你設計的程式？

至於事先在程式中加入檢查，好一點，但還不是很好，因為你還是限制了他的使用自由。所以我認為最好的方式是利用 Field.DefauldValue 的設定，或是在 Append 動作時，如果使用者未輸入則放些初始值進入必須有值的欄位裏，讓使用者享有雖然缺了些欄位資料，但仍可有新增記錄的權利，至於 DefaultVale 是要幾個空白字元或其他值，就看你日後打算怎麼再利用這些欄位了。

其實最後這個問題會回到程式設計師良心這麼個基本的人性問題上，的確，何必把欄位設成必須有值這麼辛苦？乾脆通通允許 Null 值，你設計的輕鬆，使用者用的自由，反正只要我提供的功能沒問題，誰又管得了以後這些資料再利用性如何，甚至將來再利用搞得焦頭爛額，那也是下個接案的倒霉鬼的事，大家甚至還會懷念你，說你設計時都沒問題，換個人就問題一堆。

但如果你還有一些專業的不安與不忍，那你免不了要為了將來的發展而限制現在使用者的自由，又要為怎樣減少這些限制帶來的不便而挖空心思，多寫一堆程式碼。縱使你如此苦心竭慮，卻未必能得老版或業主的認同，因為你開發的時間比人長，你寫的程式比人家囉嗦。所以，看你自己吧，老怪看的懂程式，卻未必看懂人生，該做個怎樣的程式設計師，只有你自己能決定了。

回索引

如何還原日期欄位為未輸入型態

寄件者: chiu

在一form中，建立一個textbox，但此textbox的內容為access資料庫之日期型態欄位，今天若我對textbox輸入資料後，發現輸錯日期而要將textbox內容變成空白(null)是否有辦法辦到？

老怪答：

有辦法，用 Recordset!FieldName.Value=Null 的敘述，語法如下：
Private Sub Data1_Validate(Action As Integer, Save As Integer)
    If TextBox.Text = "" Then
        Data1.Recordset.Edit
        Data1.Recordset!FieldName = Null
        Data1.Recordset.Update
    End If
End Sub

回索引

為資料記錄做群組分項統計

蘋果糖 撰寫於文章

我的資料庫用SQL，其中一個table叫維修檔,有一個欄位叫"再度叫修原因"(原因有四個,是用option選取的)，>如果要做成報表,該如何統計每個原因的次數用報表顯示出來？

老怪答：

SQLString="SELECT 再度叫修原因, Count(再度叫修原因) AS 叫修成因合計 " & _
"FROM table_維修檔 " & _
"GROUP BY 再度叫修原因"

回索引

開啟資料庫中任一資料表

寄件者: sillen

請問可不可以在把一個MDB資料庫中的資料表顯示在一個LIST元件中呢?因為我弄了一個command dialog 的元件來選取MDB的資料庫，可是不知如何再選取MDB資料庫中的資料表..... ?

老怪答：

'測試本程式請於表單布置 Data1,DBGrid1,CommonDialog1,List1
Option Explicit

Dim Db As Database
Dim Rs As Recordset

Private Sub Form_Load()
Dim Tb As TableDef
CommonDialog1.filename = ""
CommonDialog1.ShowOpen
If CommonDialog1.filename <> "" Then
Set Db = OpenDatabase(CommonDialog1.filename)
For Each Tb In Db.TableDefs
'Tabledef.Attributes 屬性是記載各資料表特性的一個屬性，其中 dbSystemObject 表示
'該資料為 MDB 系統資料表不可由使用者開啟修改。
If Not Db.TableDefs(i).Attributes And dbSystemObject Then
List1.AddItem Tb.Name
End If
Next
End If
End Sub

Private Sub Form_Unload(Cancel As Integer)
On Error Resume Next
Rs.Close
Db.Close
End Sub

Private Sub List1_Click()
Set Rs = Db.OpenRecordset(List1.List(List1.ListIndex))
Set Data1.Recordset = Rs
End Sub

回索引

用 ComBo 操作兩個欄位記錄

寄件者: Jimmy Cheng

若 Table1 為客戶檔，有業務員姓名及業務員代號兩欄位，請問如何在 Combo 中點選業務員姓名而得知業務員代號？

老怪答：

在向 Combo 增加業務員姓名時，即利用 Combo.ItemData 屬性把業務代號加進去，才能在 Combo_Click 時，直接讀取業務員代號，而不需再 Seek 一次。

  1. .把資料加到 Combo:
    Recordset.MoveFirst
    Do While Not Recordset.Eof
        combo.AddNew Recordset!業務姓名
        combo.ItemData(combo.NewIndex)=Recordset!業務代號
    Loop
  2. 取出業務代號:
    Private Sub Combo_Click
    dim var業務代號 As Long

            var業務代號=combo.ItemData(combo.ListIndex)
    End Sub

回索引

將連接的網路資料表存入本機資料庫

寄件者: Dino

請教如何將 SQL 資料庫內容轉成ACCESS的.mdb檔？

老怪答：

  1. 請依自己的網路狀況，用一 Table 連接網路資料庫。
  2. 連接上後用 SQL 的產生資料表查詢，SELECT INTO 敘述把網路資料表新增一份到 Access 資料庫來，程式碼如下：
    Option Explicit

    Dim Db As Database
    Dim Qd As QueryDef
    Private Sub Command1_Click()
        Set Db = OpenDatabase("你的本機資料庫.mdb")
        Set Qd = Db.CreateQueryDef("產生查詢的名稱/你可隨便取一個")
        Qd.SQL = "SELECT * INTO 本機資料表 FROM 網路資料表;"
        Qd.Execute
        Db.QueryDefs.Delete "產生查詢的名稱"
    End Sub

    Private Sub Form_Unload(Cancel As Integer)
        Qd.Close
        Db.Close
    End Sub

回索引

在 SQL 字串中插入 ['] 字元

倫倫~誰拿我的光碟:(~) 撰寫於文章

請問 SQL的字串是用單引號' 框起來的，但如果我要輸入某一字串,其中包含了單引號 [']，如此...字串中的 ['] 就會造成錯誤...，有沒有什麼解決辦法??

老怪答：

可以用 Chr() 函數配合 Ascii 字碼解決，
"It" & Chr(39) & "s not difficult"

回索引

回首頁

1