分類 |
標題 |
大意 |
作者 |
日期 |
| 視窗界面 | 變換同行字串之字體大小 | 老怪 | 1999/3/1 | |
| 視窗界面 | 在 Form 上列印超過 Form 長度資料 | 老怪 | 1999/3/7 | |
| 視窗界面 | 如何動態新增表單 | 物件一樣可以用動態陣列 | 老怪 | 1999/3/29 |
| 視窗界面 | 同時固定表單及顯示最小化按鈕 | 老怪 | 1999/5/4 | |
| 視窗界面 | 使用滑鼠右鍵叫出選單 | PopupMenu 方法 | 老怪 | 1999/5/9 |
| 圖形處理 | 取得 BMP 圖形顏色數 | Sun Jack | 1999/3/20 | |
| 圖形處理 | 一大圖切成數小圖 | PaintPicture 參數的使用 | 老怪 | 1999/4/8 |
| 圖形處理 | 再論 PaintPicture 的處理動作 | PictureBox 的圖層觀念 | 老怪 | 1999/4/13 |
| 圖形處理 | 簡易水中倒影試做 | PaintPicture 參數的使用 | 老怪 | 1999/4/16 |
| 控制項使用 | 即時顯示 Scroll.Value | 老怪 | 1999/3/11 | |
| 控制項使用 | 讓 Combo.AddItem 不重覆 | 老怪 | 1999/5/16 | |
| OCX 製作 | 如何作可點選顏色的 Property | OLE_COLOR 物件 | 老怪 | 1999/4/9 |
| OCX 製作 | 如何設定Default Property | 老怪 | 1999/4/9 | |
| 物件使用 | 如何更改印表機的紙張大小設定 | 正確的操作 PaperSize 屬性 | 老怪 | 1999/4/2 |
| 物件使用 | 用物件名稱字串操作物件 | Controls 集合物件的使用 | Sun Jack | 1999/5/6 |
| 流程控制 | 如何做出 VB Delay() | 老怪 | 1999/3/19 | |
| 日期時間 | 如何讓 VB Show 出百分之一秒 | 老怪 | 1999/3/20 | |
| 日期時間 | 用 Format 產生民國年份 | Sun Jack | 1999/3/21 | |
| 日期時間 | 長時間排程通知 | Timer 物件使用 | 老怪 | 1999/4/25 |
| 變數處理 | Form Unload 後變數佔用記憶體狀況 | 老怪 | 1999/4/25 |
認....真(male) 撰寫於文章
是否好的方法可用一個表單可以顯示及列印無限項結果??
老怪答：
使用變數陣列及顯示指標，再分段在 Form 上顯示，譬如：
Dim 計算結果陣列() As Variant
Dim 顯示指標 As Long
1.計算所有結果：
Redim 計算結果陣列(0)
Do
If 計算繼續 Then
計算結果陣列(0)=計算結果
ReDim Preserve 計算結果陣列(Ubound(計算結果陣列)+1)
Else
Exit Do
End IF
Loop
2.設定顯示指標
Select Case KeyCode
Case vbKeyPageUp
顯示指標=顯示指標-1
Case vbKeyPageDown
顯示指標=顯示指標+1
End Select
3.在 Form 上顯示結果
Dim I As Integer
Me.Cls
For I=顯示指標*10 TO 顯示指標*10+9 '譬如一次顯示十筆資料
Form.Print 計算結果陣列(I)
Next
以上大意如此，你再配合自己的程式修改。
w101 撰寫於文章
使用 VScroll or HScroll 按著滑鼠移動時, 可即時的傳回它的移動量嗎??
老怪答：
即時顯示移動量要使用 Scroll Event ，Change Event 是放開滑鼠才會顯示的。範例如下：
Private Sub Form_Load()
HScroll1.Max = 100
HScroll1.Min = 1
End Sub
Private Sub HScroll1_Scroll()
Text1.Text = HScroll1.Value
End Sub
依絲帖 撰寫於文章
請問一下有誰知道vb的 有沒有delay的指令...
老怪答：
jay 撰寫於文章
請問在 VB 中,如何列印出百分之一秒呢? 如 17:59:00.10 or 17:58:20:30。
老怪答：
Print Format(Now,"eemmdd")
陽光下的男孩 撰寫於文章
我寫了2個Form分別為Form1及Form2
老怪答：
eeyore 撰寫於文章
因為我的專案須要很多種報表格式 如 A4,LETTER SIZE，我使用 VB的 PRINTER.PAPERSIZE 去更改設定但是沒有作用 !!!!想請教各位先進,有那一個 C++ OR API OR VB 指令可以動態設定印表機的狀態。
老怪答：
Option Explicit
Private Type BITMAPINFOHEADER '40 bytes
biSize As Long
biWidth As Long
biHeight As Long
biPlanes As Integer
biBitCount As Integer
biCompression As Long
biSizeImage As Long
biXPelsPerMeter As Long
biYPelsPerMeter As Long
biClrUsed As Long
biClrImportant As Long
End Type
Private Type BITMAPFILEHEADER
bfType As Integer
bfSize As Long
bfReserved1 As Integer
bfReserved2 As Integer
bfOffBits As Long
End Type
Private Sub Command1_Click()
Dim FileName As String
Dim ff As Integer
Dim FileHeader As BITMAPFILEHEADER
Dim InfoHeader As BITMAPINFOHEADER
FileName = "h:\delete.bmp"
'read the file header info
ff = FreeFile
Open FileName For Binary Access Read As #ff
Get #ff, , FileHeader
Get #ff, , InfoHeader
Close #ff
MsgBox InfoHeader.biBitCount & " (" & 2 ^ InfoHeader.biBitCount & "
colours)"
End Sub老怪附註：
只能適用 BMP 圖檔，其他格式圖檔會產生程式錯誤。
Tako _ 撰寫於文章
請問在VB下讀入一個BMP檔,如何把它切成4x4個picture物件呢?? 是說一個800x600的bmp檔.. 要切成50x37的16個picture物件...有辦法嗎??
老怪答：
'範例功能：一大圖切成數小圖
'測試本範例請於表單布置 Text1(0),Text1(1),Picture1,Picture2
Option Explicit
Private Sub Command1_Click()
Dim XNum As Integer, YNum As Integer
Dim I As Integer, J As Integer
Dim PWidth As Single, PHeight As Single
'把 Text 內容轉成小圖縱橫切割數
XNum = Val(Text1(0).Text)
YNum = Val(Text1(1).Text)
'換算每塊小圖的長寬
With Picture1
PWidth = .ScaleWidth / XNum
PHeight = .ScaleHeight / YNum
End With
'依小圖長寬決定 Picture2 長寬
With Picture2
.Width = PWidth + .Width - .ScaleWidth
.Height = PHeight + .Height - .ScaleHeight
End With
'把 Picture1 圖片一小塊一小塊貼到 Picture2 上，再把 Picture2.Image 存
檔。
For I = 0 To YNum - 1
For J = 0 To XNum - 1
With Picture2
.AutoRedraw = True
.PaintPicture Picture1.Picture, .ScaleLeft, .ScaleTop, , _
, J * PWidth, I * PHeight, .ScaleWidth, .ScaleHeight
.AutoRedraw = False
SavePicture .Image, "c:\test\" & Right(String(3, "0") _
& Trim(Val(I)) & Trim(Val(J)), 3) & ".bmp"
End With
Next
Next
End Sub
Private Sub Form_Load()
Picture1.AutoSize = True
Picture2.Visible = False
Text1(0).Text = ""
Text1(1).Text = ""
Picture1.Picture = LoadPicture("c:\temp\a18a.jpg")
End Sub
Private Sub Text1_KeyPress(Index As Integer, KeyAscii As Integer)
'KeyAscii 32 以下是一些控制鍵，攔截會造成操作障礙
If KeyAscii >= 33 Then
If KeyAscii <= vbKey9 And KeyAscii >= vbKey0 Then
Else
'把 KeyAscii 設為 0 就是取消輸入
KeyAscii = 0
MsgBox "不可輸入非數字字元"
End If
End If
End Sub
yclin 撰寫於文章
請問以VB製作OCX, 其Property 中如何出現backcolor這property(可點選顏色)?
老怪答：
當你把 BackColor 傳入及傳回值設為 OLE_COLOR 就可以在屬性窗點選顏色。如下例：
Public Property Get BackColor() As OLE_COLOR
BackColor = UserControl.BackColor
End Property
Public Property Let BackColor(ByVal New_BackColor As OLE_COLOR)
UserControl.BackColor() = New_BackColor
PropertyChanged "BackColor"
End Property
我竟然是小呆瓜)
Picture1沒有載入圖形
Picture1.PaintPicture Picture2,1,1,,,,,,vbSrcCopy
Form1.PaintPicture Picture1,1,1,,,,,,vbSrcCopy
^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
結果有Error？PaintPicture只能把圖畫在物件上而不能真正寫入物件嗎!?
老怪答：
我簡化一些來說吧，你可以把 VB 繪圖元件看成是有三層面版，底層稱做 Picture層，中層叫做 Image 層，而上層叫做 Paint Show 層，所有繪圖方法Line,Circle,PaintPicture,Cls 等，畫出來的影像都是在 Paint Show 層上，至於用LoadPicture or Set Object.Picture=PictureObject 的圖形，則是放在 Picture 層上。
基本上 Paint Show 層的影像是無法被指定或擷取的，也就是說繪圖方法Line,Circle,PaintPicture,Cls 等繪出的圖形，只供顯示用，當你的 Form 被其他Form 遮蔽後，就消失不見了。而以為用繪圖方法Line,Circle,PaintPicture,Cls 是畫在 Picture 層上，也是對 VB 繪圖元件動作不了解所至。
那這麼說繪圖元件的繪圖方法繪出的圖怎樣才能被指定或擷取呢，那就是 Image 層的做用了。Image 層的構成是它首先會把 Picture 層影像複製一份當底(※注意！就算 Object.Picture 未載入或指定圖形，Image 一樣有意義，因為這時它會以繪圖物件的 BackColor 為 Image。)然後會依繪圖物件的 AutoRedraw 狀況決定繪圖方法是否會把圖形畫到 Image 上。AutoRedraw=False 時，不管繪圖元件怎麼畫，Image 都不會改變，維持原來的 Picture 層的 Image ，但如果把 AutoRedraw=True 時，則所有的繪圖方法都會畫到 Image 層上，而與原存在的 Picture Image 結合在一起。
所以如果繪圖目的只是 Show 給使用者看，那麼 AutoRedraw 屬性可以維持 Default 的 False 值，但如果畫完後要指定給其他的物件 or SavePicture ，則一定要 AutoRedraw= True。
OK ，最後總整理：
- 你要在繪圖元件上畫圖形後指定給其他物件或儲存圖檔。
- 讓該繪圖元件的 AutoRedraw=True。
- 用繪圖方法在繪圖元件上繪圖。
- 把 繪圖元件.Image 指定給第二個物件或儲存，如果以呆瓜的問題就是：
Picture2.PaintPicture Picture1.Image
'本範例是用 VB PictureBox 物件模擬常在 Java Applet 出現的水中倒影物件效果，
'原理是把 PictureBox 中的圖片看做是掃瞄線的集合，然後利用 Timer 物件配合
'For ... Next 迴圈，一條一條搬到另一個 PictureBox 裏，不過搬的過程中要把它
'向左向右移一下，就有波影盪漾的感覺。
'測試本範例請於表單上布置 Picture1,2、Command1、Timer1。
Option Explicit
'決定左右波大小
Private Const 水平偏移值 As Integer = 5
'決定圖線左移或右移的指標
Dim TurnBackA As Long, TurnBackB As Long
Private Sub Command1_Click()
If Command1.Caption = "開始倒影" Then
With Picture2
.PaintPicture Picture1.Picture, .ScaleLeft, .ScaleTop
End With
Timer1.Enabled = True
Command1.Caption = "結束倒影"
Else
Timer1.Enabled = False
Picture2.Cls
Command1.Caption = "開始倒影"
End If
End Sub
Private Sub Form_Load()
'布置各控制項位置及大小
With Picture1
Picture2.ScaleMode = 3
.ScaleMode = 3
.AutoSize = True
.Picture = LoadPicture("c:\temp\sisbkgnd.bmp")
.Move Me.ScaleLeft, .ScaleTop
Picture2.Move Me.ScaleLeft, Me.ScaleTop + .Height, .Width, .Height
Me.Width = .Width + Me.Width - Me.ScaleWidth
Me.Height = .Height * 2 + Command1.Height + 240 + _
Me.Height - Me.ScaleHeight
Me.Caption = "VB 水中倒影範例"
Command1.Move (Me.ScaleWidth - Command1.Width) / 2, .Height * 2 +
120
Command1.Caption = "開始倒影"
End With
With Timer1
.Enabled = False
.Interval = 66
End With
'先設定波紋右移
TurnBackA = 1
TurnBackB = 1
End Sub
Private Sub Timer1_Timer()
'第一條線的左右移動量
Static OffStart As Long
'每條圖線左右移動量
Static Offset As Long
Dim I As Long
With Picture2
TurnBackA = 1 * TurnBackB
'逐點貼上圖線的迴圈
For I = 0 To .ScaleHeight - 1
.PaintPicture Picture1.Picture, Offset, I, .Width, 1, _
0, I, .Width, 1
If Abs(Offset) = 水平偏移值 Then
Offset = 0
TurnBackA = TurnBackA * -1
Else
Offset = Offset + (1 * TurnBackA)
End If
DoEvents
Next
End With
If Abs(OffStart) = 水平偏移值 Then
OffStart = 0
TurnBackB = TurnBackB * -1
Else
OffStart = OffStart + (1 * TurnBackB)
End If
Offset = OffStart
End Sub
hear 撰寫於文章
感謝大家熱心的回答. 記憶體的控制實在是程式寫作很重要的部分, 控制得好, 資源才能有效利用, 程式效能也才能發揮..我對COM並不熟悉, 根據各位的回答, 整理如下, 不知道有沒有錯誤:Form Unload之後, 會釋放Form內部Public與Private的變數記憶體空間,
不是這樣的，
b8740038撰寫於文章
我要每3小時執行一個程序，除了使用TIMER外,還有啥方法??如果用TIMER控制項不就要使用3個??因為,一個TIMER的INTERVAL最多只有1MINS多???
老怪答：
拜託，那如果你要某年某月的某一天怎麼辦？每秒檢查一次過了三個小時沒，就這樣。
Dim Startime As Date
Sub Form_Load()
Startime=Now()
Timer1.Interval=1000
End Sub
Sub Timer1_Timer()
If Hour(Now-Startime)>=3 Then
MsgBox "過了三小時"
Startime=Now()
End If
End Sub
%重新感覺彼此% 撰寫於文章
在vb的表單中會出現右上角三個按鈕的屬性好像只有 BorderStyle=2時,其他的(=0,1,3,4,5)都只有x or nothing, 然而BorderStyle=2時,表單大小又可用滑鼠拖拉邊界放大縮小。請問我要怎麼設定才能做到 又可使用最小化按鈕又可固定邊界 滑鼠不能拖拉邊界改變表單大小???
老怪答：
想做就去做吧 撰寫於文章
請問在如何在VB中使用滑鼠右鍵叫出選單(menu)？我希望不要在 MenuLine 上顯示，只讓使用者透過滑鼠右鍵來做選單的選擇。
老怪答：
Option Explicit
Private Sub Form_Load()
MenuName.Visible = False
End Sub
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single,
Y As Single)
If Button = 2 Then
Me.PopupMenu MenuName
End If
End Sub
菜鳥一壘手 撰寫於文章
如何寫一個程式讓相同的item只出現一次,在additem的同時就順便檢查有沒有重複的,沒有重複的才additem.有重複的就跳過？
老怪答：
Option Explicit
Private Sub Combo1_KeyPress(KeyAscii As Integer)
Dim I As Long
Dim Duplicate As Boolean
'壓下 Enter 表示輸入完畢
If KeyAscii = 13 Then
'設定輸入未重覆預設值
Duplicate = False
If Combo1.ListCount = 0 Then
Combo1.AddItem Combo1.Text
Else
'檢查所有輸入記錄是否重覆
For I = 0 To Combo1.ListCount - 1
If Combo1.List(I) = Combo1.Text Then
Duplicate = True
MsgBox "輸入項重複"
Exit For
End If
Next
'如果不重覆才加入該項
If Not Duplicate Then
Combo1.AddItem Combo1.Text
End If
End If
End If
End Sub