A*================================================================
     A                                      DSPSIZ(24 80 *DS3)
     A                                      CF01 CF07 CF13 CF19
     A                                      CF02 CF08 CF14 CF20
     A                                      CF03 CF09 CF15 CF21
     A                                      CF04 CF10 CF16 CF22
     A                                      CF05 CF11 CF17 CF23
     A                                      CF06 CF12 CF18 CF24
     A                                      HELP(01)
     A                                      VLDCMDKEY(26)
     A*================================================================
     A          R MAIN                      OVERLAY FRCDTA
     A  27                                  PUTOVR
     A                                  1 30'Find Message By Text'
     A                                      DSPATR(HI UL) COLOR(WHT)
     A                                  4  2'The program finds in a message fil-
     A                                      e all message having'
     A                                      COLOR(BLU)
     A                                  5  2'1st or 2nd levels text LIKE specif-
     A                                      ified template.'
     A                                      COLOR(BLU)
     A                                  6 10'Messages:'
     A                                  7 10'Message File . . .'
     A            $FILE         10A  B  7 29
     A                                  7 41'Message File Name'
     A                                  8 10'Library. . . . . .'
     A            $LIBL         10A  B  8 29
     A  22                                  OVRDTA
     A                                  8 41'Library name or any of'
     A                                  9 41'*CURLIB *LIBL'
     A                                 10 10'Message text LIKE'
     A            $DESC         50A  B 10 29 CHECK(LC)
     A                                 11 32'%  - zero or more any characters'
     A                                 12 32'_  - one character (any)'
     A                                 13 32'\% - the % character'
     A                                 14 32'\_ - the _ character'
     A                                 15 32'e.g. %Program #\_%'
     A                                 16 10'Search in 2nd level text also. .'
     A            $LVL2          1A  B 16 43 VALUES('Y' 'N')
     A                                 16 45'either Y or N'
     A                                 17 10'Match Case . . . . . . . . . . .'
     A            $CASE          1A  B 17 43 VALUES('Y' 'N')
     A                                 17 45'either Y or N'
     A  22        NDALL         21   O 19 10           OVRDTA
     A  22        NNALL         10  0O 19 33 EDTCDE(3) OVRDTA
     A  22        NDSEL         21   O 20 10           OVRDTA
     A  22        NNSEL         10  0O 20 33 EDTCDE(3) OVRDTA
     A                                 23  2'F3=Exit'
     A                                      COLOR(BLU)
     A  20                             23 12'F8=View Found Messages List'
     A                                      COLOR(BLU)
     A  20                             23 41'F9=Copy List Into File'
     A                                      COLOR(BLU)
     A*================================================================
     A          R MSGSFL                    SFL
     A                                      SFLMSGRCD(24)
     A            MSGKEY                    SFLMSGKEY
     A            MSGPQ                     SFLPGMQ
     A*================================================================
     A          R MSGCTL                    SFLCTL(MSGSFL)
     A                                      OVERLAY
     A                                      SFLDSP
     A                                      SFLDSPCTL
     A                                      SFLINZ
     A                                      SFLSIZ(2)
     A                                      SFLPAG(1)
     A N25                                  SFLEND
     A            MSGPQ                     SFLPGMQ
     A*================================================================
     A          R WCOPY                     WINDOW(11 24 4 31 *NOMSGLIN)
     A                                  1  2'Enter File Name To Copy Into:'
     A                                      DSPATR(HI UL) COLOR(WHT)
     A                                  2  3'File . . . . . .'
     A            $FNAME        10   I  2 20
     A                                  3  3'Library. . . . .'
     A            $LNAME        10   I  3 20
     A                                  4  5'F12=Cancel'
     A                                      COLOR(BLU)
     A*================================================================
     A          R WHELP                     WINDOW(15 12 3 55 *NOMSGLIN)
     A                                  1 22'Author:'
     A                                      DSPATR(HI UL) COLOR(WHT)
     A                                  2  3'Victor Voilevitch'
     A                                      COLOR(BLU)
     A                                  3  3'http:/www.geocities.com/SiliconVal-
     A                                      ley/Haven/6243/'
     A                                      COLOR(BLU)
     A*================================================================