; dressup script OUTCHAT section
;       Written by Paul Jacobs, 12-6-96
;               known on The Palace as
;               DataŠ
;
;       Commands are:   dress on    (turns script on)
;                       dress off   (turns script off)
;                       dress naked (strips person clicked on of props)
;                       dress me    (copies props of person clicked on)
;                       dress you   (sends your props to person clicked on)
;
;       This script oiginally uploaded to EricD's Iptscrae archive
dressup GLOBAL
        { "$1" GREPSUB option =
          { 0 dressup =
            "Dressup script is ON" LOGMSG } "on" option == IF
          { 1 dressup =
            "Dressup script is OFF" LOGMSG } "off" option == IF
          { "dress " option & send =
           { ";dd [" send =
              WHOME NBRUSERPROPS i =
              { i 1 - i =
                send i USERPROP ITOA & " " & send = } { i } WHILE
              send "] SETPROPS" & send =
            } "you" option == IF
            send WHOTARGET PRIVATEMSG
          } WHOTARGET IF
          "" CHATSTR =
        } CHATSTR LOWERCASE "^dress (.*)$" GREPSTR IF


; dressup script INCHAT section
;       Written by Paul Jacobs, 12-6-96
;               known on The Palace as
;               DataŠ
dressup GLOBAL
        { { "Sorry, my dressup script is turned off" WHOCHAT PRIVATEMSG }
          { "$1" GREPSUB STRTOATOM EXEC } dressup IFELSE
 "" CHATSTR =
        } CHATSTR "^;dd (.*)$" GREPSTR WHOME WHOCHAT !=  AND IF

        { { "Sorry, my dressup script is turned off" WHOCHAT PRIVATEMSG }
          { "$1" GREPSUB option =
            { NAKED
            } "naked" option == IF
            { ";dd [" send =
              WHOME NBRUSERPROPS i =
              { send i 1 - USERPROP ITOA & " " & send =
                i-- } {i} WHILE
              send "] SETPROPS" & send =
              send WHOCHAT PRIVATEMSG
            } "me" option == IF
          } dressup IFELSE
          "" CHATSTR =
        } CHATSTR "^dress (.*)$" GREPSTR WHOME WHOCHAT != AND IF