;************************************************************

;Script :  New Rainbow Beam
;Author :  Michael Lampkin
;Date   :  11-15-96

;Desc   :  Puts a Rainbow beam from user to cursor 44 pixels
;          high (y axis), places a prop at the target site...
;          uses sound file found at palace.minds.com port 9998
;          follow the web link... or change it to a normal sound.

;Syntax :  rbeamer <propname>


  {


  ;Set beam start position  & target loc

    POSX 22 + x =
    POSY y =

    MOUSEPOS my = mx =

  ;Prepare to draw beam, set up colors table
  ;User may add or delete colors from the table w/o ill effect
  ; simply add or delete a color set "[ r g b ]"

    1 PENSIZE
    PENFRONT

    [ [ 0   128 255 ]
      [ 0   255 255 ]
      [ 0   255 128 ]
      [ 0   255 0   ]
      [ 128 255 0   ]
      [ 255 255 0   ]
[ 255 255 128 ]
      [ 255 255 255 ]
      [ 255 128 0   ]
      [ 255 0   0   ] ] coltab =

    coltab LENGTH numcol =

    ;Loop thru color table & draw beam 44 pixels high

    0 i =
    {
      coltab i numcol % GET curcol =
      curcol 0 GET r =
      curcol 1 GET g =
      curcol 2 GET b =
      r g b PENCOLOR
      x y mx my i + LINE
      x y mx my i - LINE
      i ++
}
    { i 22 < } WHILE


  ;now clear the mess we've made... and make a sound (minds sound)

    ")cmmplc" SAY

    0 i =
    {
      PAINTUNDO
      PAINTUNDO
      i ++
    }
    { i 22 < } WHILE

  ;if a prop was named, place at end of beam

    MOUSEPOS my = mx =

    "$1" GREPSUB mx 20 - my 10 - ADDLOOSEPROP

  ;so we dont look like we are talking to ourself

    "" CHATSTR =

  }   CHATSTR "rbeamer (.*)$" GREPSTR IF