A few people have asked about the alien "scan" script that I have been 
using of 
late.  So here it is.

WARNING: I had to tone this script down twice before I came up with this 
incarnation.  Even so, this script will spam the server for about 2 
seconds (others 
will hang) and probably contains 50+ events (and 100 will get you 
terminated for a 
while).  So, be considerate, don't use it too often - timing is 
everything.  Any 
effect that is used too much gets annyoing really fast anyway.

I have a version ready to go into the tricorder (or similar prop) once 
props are 
scriptable (no pressure :-) but for now, but this in your OUTCHAT script.

--------------- Scan 1.0b1

  { 
      PENFRONT
; we want the effect to scan over the target, so the painting must be on top

      MOUSEPOS y = x =
; we will be using the target point a bunch of times, so we will use 
variables

             1 PENSIZE

      255 255 0 PENCOLOR ; yellow (yes red+green=yellow)

; the beams crossing out of the eyes
      POSX 13 + POSY 23 - x 30 - y 30 - LINE
      POSX 13 + POSY 23 - x 30 - y 30 + LINE
      POSX 7 - POSY 19 - x 30 + y 30 - LINE
      POSX 7 - POSY 19 - x 30 + y 30 + LINE

; the cross-hair in the middle
      2 PENSIZE

      0 255 0 PENCOLOR

      x 5 - y  x 5 + y LINE
      x y 5 - x y 5 + LINE

; the four corners of the target
      255 0 0 PENCOLOR

      x 30 - y 30 - x 20 - y 30 - LINE
      x 30 - y 30 - x 30 - y 20 - LINE

      x 30 + y 30 - x 20 + y 30 - LINE
      x 30 + y 30 - x 30 + y 20 - LINE

      x 30 - y 30 + x 20 - y 30 + LINE
      x 30 - y 30 + x 30 - y 20 + LINE

      x 30 + y 30 + x 20 + y 30 + LINE
      x 30 + y 30 + x 30 + y 20 + LINE

; a little sound effect
          ")fazein" SAY

; scanning horizontally
      0 255 0 PENCOLOR

          1 PENSIZE

      -25 d  =

      {
         j ++
             x d + y 25 - x d + y 25 + LINE
         d 5 + d =
      } { j 11 < } WHILE

; erase horizontal
             0 i =
      { i ++ PAINTUNDO } { i 11 < } WHILE

; vertical scan lines
      -25 d  =

      {
         k ++
             x 25 + y d + x 25 - y d +
                 LINE
         d 5 + d =
      } { k 11 < } WHILE

; erase them and all the other lines
          0 i =
      { i ++ PAINTUNDO } { i 25 < } WHILE

; remove word "scan" from the CHATSTR so it doesn't go in the balloon
      "" CHATSTR =

   } CHATSTR "scan" == IF