LSDateFormat

Formats the date portion of a date/time value using the locale convention. Like DateFormat LSDateFormat returns a formatted date/time value. If no mask is specified, LSDateFormat returns a date value using the locale-specific format.

Syntax

LSDateFormat(date [, mask ])

date

Date/time object in the period from 100 AD to 9999 AD.

mask

Set of characters that are used to show how ColdFusion should display the date:

d -- Day of the month as digits with no leading zero for single-digit days.
dd -- Day of the month as digits with a leading zero for single-digit days.
ddd -- Day of the week as a three-letter abbreviation.
dddd -- Day of the week as its full name.
m -- Month as digits with no leading zero for single-digit months.
mm -- Month as digits with a leading zero for single-digit months.
mmm -- Month as a three-letter abbreviation.
mmmm -- Month as its full name.
y -- Year as last two digits with no leading zero for years less than 10.
yy -- Year as last two digits with a leading zero for years less than 10.
yyyy -- Year represented by four digits.
gg -- Period/era string. Currently ignored, but reserved for future use

Usage

When passing date/time value as a string, make sure it is enclosed in quotes. Otherwise, it is interpreted as a number representation of a date/time object returning undesired results.

Examples

<!--- This shows LSDateFormat --->
<HTML>
<HEAD>
<TITLE>LSDateFormat Example</TITLE>
</HEAD>

<BODY>
<H3>LSDateFormat Example</H3>

<P>LSDateFormat formats the date portion of a date/time
value using the locale convention. 


<!--- loop through a list of possible locales and
show date values for Now()--->
<CFLOOP LIST="#Server.Coldfusion.SupportedLocales#"
INDEX="locale" DELIMITERS=",">
    <CFSET oldlocale = SetLocale(locale)>

    <CFOUTPUT><P><B><I>#locale#</I></B><BR>
        #LSDateFormat(Now(), "mmm-dd-yyyy")#<BR>
        #LSDateFormat(Now(), "mmmm d, yyyy")#<BR>
        #LSDateFormat(Now(), "mm/dd/yyyy")#<BR>
        #LSDateFormat(Now(), "d-mmm-yyyy")#<BR>
        #LSDateFormat(Now(), "ddd, mmmm dd, yyyy")#<BR>
        #LSDateFormat(Now(), "d/m/yy")#<BR>
        #LSDateFormat(Now())#<BR>        
        <Hr noshade>
    </CFOUTPUT>

</CFLOOP>

</BODY>
</HTML>

CFML Language Reference
Chapter 2 : ColdFusion Functions