ToBinary

Returns the binary representation of Base64 encoded data.

See CFFILE for information about loading and reading binary data, CFWDDX for information about serializing and deserializing binary data, and IsBinary and ToBase64 for checking for binary data and converting it into printable form. See also Len for determining the length of a binary object.

Syntax

ToBinary(string_in_Base64 or binary_value)

string_in_Base64 or binary_value

String in Base 64 that is to be converted to binary or binary value that is to be tested to ensure that it is an acceptable binary value.

Usage

Base 64 provides 6 bit encoding of 8-bit ASCII characters.If you receive data in Base 64, you can re-create the actual binary object that it represents, such as a .gif , .jpeg, or executable file, by using the ToBinary function.

Examples

<!--- This example shows the use of ToBinary and ToBase64 --->
<HTML>
<HEAD>
<TITLE>
ToBinary Example
</TITLE>
</HEAD>

<BASEFONT FACE="Arial, Helvetica" SIZE=2>
<BODY  bgcolor="#FFFFD5">

<H3>ToBinary Example</H3>

<!----------------------------------------------------------------------
Initialize data.
----------------------------------------------------------------------->
<CFSET charData ="">
<!----------------------------------------------------------------------
Create a string of all ASCII characters (32-255) and concatenate them 
together.
----------------------------------------------------------------------->
<CFLOOP index="data" from="32" to="255">
    <CFSET ch=chr(data)>
    <CFSET charData=charData & ch>
</CFLOOP>
<P>
The following string is the concatenation of all characters (32 to 255) 
from the ASCII table.<BR>
<CFOUTPUT>#charData#</CFOUTPUT>
</P>

<!----------------------------------------------------------------------
Create a Base 64 representation of this string.
----------------------------------------------------------------------->
<CFSET data64=toBase64(charData)>

<!----------------------------------------------------------------------
Convert string to binary.
----------------------------------------------------------------------->
<CFSET binaryData=toBinary(data64)>
<!----------------------------------------------------------------------
Convert binary back to Base 64.
----------------------------------------------------------------------->
<CFSET another64=toBase64(binaryData)>
<!----------------------------------------------------------------------
Compare another64 with data64 to ensure that they are equal.
----------------------------------------------------------------------->
<CFIF another64 eq data64>
    <H3>Base 64 representation of binary data is identical to the Base 64 
    representation of string data.</H3>
<CFELSE>
    <H3>Conversion error.</H3>
</CFIF>
</BODY>
</HTML>

CFML Language Reference
Chapter 2 : ColdFusion Functions